home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib10.dsk / LOWER CASE DEMO.bas < prev    next >
BASIC Source File  |  2023-02-26  |  2KB  |  59 lines
  1. 1  REM  ***************************
  2. 2  REM  *  LOWER CASE DEMO        *
  3. 3  REM  *  BY BEN E. COLLEY       *
  4. 4  REM  *  COPYRIGHT (C) 1982     *
  5. 5  REM  *  BY MICRO-SPARC INC     *
  6. 6  REM  *  LINCOLN, MA. 01773     *
  7. 7  REM  *  ALL RIGHTS RESERVED    *
  8. 8  REM  ***************************
  9. 10 :
  10. 20 :
  11. 30  REM  UPPER - LOWER CASE DEMONSTRATION
  12. 40 :
  13. 50 :
  14. 60  TEXT : HOME 
  15. 70  HTAB 8: INVERSE : PRINT "UPPER CASE - LOWER CASE": NORMAL 
  16. 80  HTAB 13: PRINT "DEMONSTRATION"
  17. 85  POKE 34,2
  18. 90  PRINT  CHR$(4);"BLOAD LC OUTPUT"
  19. 100  VTAB 5: HTAB 10: PRINT "ASCII CHARACTER SET"
  20. 110  VTAB 7
  21. 120  FOR I = 0 TO 127:LC$ = LC$ + CHR$(I): NEXT 
  22. 130  CALL 768,LC$
  23. 140  FOR I = 1 TO 4000: NEXT 
  24. 150  HTAB 1: VTAB 5: CALL  -958
  25. 160  PRINT : PRINT "NOW YOU MAY TRY THE INPUT ROUTINE"
  26. 170  PRINT "ESC KEY SIGNALS CAPITAL LETTERS"
  27. 180  DIM IN$(5)
  28. 190  FOR I = 1 TO 5
  29. 200  PRINT I;") ";
  30. 210  GOSUB 400
  31. 220 IN$(I) = LC$
  32. 230  NEXT 
  33. 240  REM    PRINT THE MATRIX
  34. 250  VTAB 14
  35. 260  HTAB 9: PRINT "HERE IS WHAT YOU KEYED"
  36. 270  FOR I = 1 TO 5
  37. 280  PRINT I;") ";
  38. 290  CALL 768,IN$(I): PRINT 
  39. 300  NEXT 
  40. 310  VTAB 23: PRINT "THAT'S ALL!";
  41. 320  END 
  42. 400  REM   LC INPUT
  43. 410 LC$ = "":UC = 0
  44. 420  FOR QL = 1 TO 2  STEP 0
  45. 430  GET A$:AC =  ASC(A$)
  46. 440  IF (AC >31  AND AC <65)  OR AC >90  THEN  PRINT A$;:UC = 0
  47. 450  IF AC = 27  THEN UC = 1
  48. 460  IF   NOT UC  AND AC >64  AND AC <91  THEN AC = AC +32: PRINT A$;
  49. 470  IF UC  AND AC >64  AND AC <91  THEN  INVERSE : PRINT A$;: NORMAL :UC = 0
  50. 480  IF AC < >27  AND AC < >13  AND AC < >8  THEN A$ =  CHR$(AC):LC$ = LC$ +A$
  51. 490 QM =  LEN(LC$)
  52. 500  IF AC = 8  AND QM = 1  THEN  IF  ASC(LC$) >31  THEN  PRINT A$;: CALL  -868
  53. 510  IF AC = 8  AND QM = 1  THEN LC$ = ""
  54. 520  IF AC = 8  AND QM >1  THEN  IF  ASC( RIGHT$(LC$,1)) >31  THEN  PRINT A$;: CALL  -868
  55. 530  IF AC = 8  AND QM >1  THEN LC$ =  LEFT$(LC$,QM -1)
  56. 540  IF AC = 13  THEN  PRINT :QL = 2
  57. 550  NEXT 
  58. 560  REM  ON EXIT LC$ IS UPPER/LOWER CASE STRING
  59. 570  RETURN